F1F2-selective NMR: Pulse programs¶
All pulse programs are in Bruker format.
Overview¶
Currently, the following pulse programs are available for download:
| Experiment | Download | Comment |
|---|---|---|
| F1F2-selective HN(CA)NH | f1f2hncanh |
|
| F1F2-selective HN(CA)NH | f1f2hncanh3d |
pseudo-3D version |
| F1F2-selective NOESY-[1H, 15N]-HSQC | f1f2nNnoesygpsi |
|
| F1F2-selective NOESY-[1H, 15N]-HSQC | f1f2nNnoesygpsi3d |
pseudo-3D version |
| F1F2-selective NOESY-[1H, 13C]-HSQC | f1f2nCnoesygp |
|
| F1F2-selective NOESY-[1H, 13C]-HSQC | f1f2nCnoesygp3d |
pseudo-3D version |
| F1F2-selective [15N]-R1ρ relaxation dispersion | f1f2Nr1rho |
|
| F1F2-selective [15N]-R1ρ relaxation dispersion | f1f2Nr1rho3d |
pseudo-3D version |
| F1F2-selective [15N]-R1ρ relaxation dispersion | f1f2Nonr1rho4d |
pseudo-4D version |
| F1F2-selective [15N]-ZZ exchange | f1f2Nzzhsqcgpsi |
F1F2-selective NMR spectroscopy¶
The F1F2-selective pulse sequences are introduced in these publications:
Walinda, E., Morimoto, D., Shirakawa, M., and Sugase K.,
F1F2-selective NMR spectroscopy
J Biomol NMR 2017, 68(1), 41–52.
Nishizawa, M., Walinda, E., Morimoto, D., and Sugase, K.
Pinpoint analysis of a protein in slow exchange using F1F2-selective ZZ-exchange spectroscopy: assignment and kinetic analysis.
J Biomol NMR 2020, in press
Please feel free to inquire, if you have questions regarding the setup of these experiments.
F1F2-selective HN(CA)NH¶
This pulse program is a F1F2-selective HN(CA)NH experiment to probe a single resonance. For the pseudo-3D version, which acquires 2D spectra for multiple residues, please see the next section.
You can download the pulse program here - f1f2hncanh
;f1f2hncanh
;
;avance-version (05/23/2017)
;2D F1F2-selective HN(CA)NH
;2D sequence with
; inverse correlation for triple resonance using multiple
; inept transfer steps
;on/off resonance Ca and C=O pulses using shaped pulse
;phase sensitive (t1)
;phase sensitive using Echo/Antiecho-TPPI gradient selection (t1)
;using semi-constant time in t1
;
; F1(H) -(CP)-> F2(N) -> F3(Ca) -> F2(N,t1) -> F1(H,t2)
;
;E. Walinda, D. Morimoto, M. Shirakawa, and K. Sugase,
; J. Biomol. NMR, 2017, 68 (1), 41-52
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=
#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>
define pulse Pcp
"Pcp=10.8ms"
"p2=p1*2"
"p22=p21*2"
"p26=pcpd1"
"plw0=0"
"plw10=plw1*pow(p1/(250000/cnst9),2)" ; 1H CP power
"plw22=plw3*pow(p21/(250000/cnst9),2)" ; 15N CP power
"plw16=plw3*pow((p21/pcpd3),2)" ; 15N decoupling power
"plw19=plw1*pow((p1/pcpd1),2)" ; 1H decoupling power
"spw1=plw1*pow((p1/(p11*0.5889)),2)" ; Water-flip-back pulse power
"cnst5=sfo1*cnst19-o1*1000000"
"cnst6=sfo3*cnst0-o3*1000000"
"d11=30m"
"d21=5.5m"
"d23=12.4m"
"d26=2.3m"
"d27=12.5m"
"d0=d23/2-p14/2"
"d17=3u"
"d29=d23/2-p14/2-p26-d21-4u"
"d30=d23/2+p14/2+d17"
"in0=inf1/4"
"FACTOR2=d30*10000000*2/td1"
"in30=FACTOR2/10000000"
"if ( in30 > in0 ) { in17 = 0; } else { in17=in0-in30; }"
"if ( in30 > in0 ) { in30 = in0; }"
"in29=in0"
"DELTA=d21-p16-d16"
"DELTA1=p16+d16+4u"
"spoff2=0"
"spoff3=0"
"spoff5=bf2*(cnst21/1000000)-o2"
"spoff8=0"
"spoff9=0"
"acqt0=0"
baseopt_echo
1 ze
d11 pl16:f3
2 d11 do:f3
3 d1 pl0:f1
50u UNBLKGRAD
(p11:sp1 ph2):f1
4u
4u pl1:f1 fq=cnst5 (sfo hz):f1
(p1 ph0):f1
4u pl10:f1 pl22:f3 fq=cnst6 (sfo hz):f3
(Pcp ph1):f1 (Pcp ph0):f3 ; cross polarization
4u pl19:f1 fq=0 (sfo hz):f1 fq=0 (sfo hz):f3 pl3:f3
;*******************************************************
(p21 ph1):f3
p16:gp1
d16
(ralign (p26 ph3):f1 (p21 ph4):f3 )
d23 cpds1:f1 ph0
(center (p14:sp3 ph0):f2 (p22 ph0):f3 )
d23
(p21 ph0):f3
4u do:f1
(p26 ph1):f1
p16:gp4
d16
(p26 ph3):f1
4u cpds1:f1 ph0
;******************************************************* N -> Ca
(p13:sp2 ph0):f2
d27
(p14:sp5 ph0):f2
d27
(center (p24:sp9 ph0):f2 (p22 ph0):f3 )
d27
(p14:sp5 ph0):f2
d27
(p13:sp8 ph0):f2
;******************************************************* Ca -> N
4u do:f1
(p26 ph1):f1
p16:gp5
d16
(p26 ph3):f1
4u cpds1:f1 ph0
;******************************************************* 15N chemical shift evolution
(p21 ph5):f3
d30
(p14:sp5 ph0):f2
d30
(p22 ph8):f3
d17
(p14:sp5 ph0):f2
d17
(p14:sp3 ph0):f2
d0
(p14:sp5 ph0):f2
d29
;*******************************************************
4u do:f1
(p26 ph1):f1
p16:gp2*EA
d16
DELTA pl1:f1
;******************************************************* PEP
(center (p1 ph0):f1 (p21 ph6):f3 )
d26
(center (p2 ph0):f1 (p22 ph0):f3 )
d26
(center (p1 ph1):f1 (p21 ph7):f3 )
d26
(center (p2 ph0):f1 (p22 ph0):f3 )
d26
(p1 ph0):f1
DELTA1
(p2 ph0):f1
p16:gp3
d16 pl16:f3
4u BLKGRAD
go=2 ph31 cpd3:f3
d11 do:f3 mc #0 to 2
F1EA(calgrad(EA) & calph(ph7, +180), caldel(d0, +in0) & caldel(d17, +in17) & caldel(d29, +in29) & caldel(d30, -in30) & calph(ph5, +180) & calph(ph31, +180))
exit
ph0 = 0
ph1 = 1
ph2 = 2
ph3 = 3
ph4 = 1 3
ph5 = 0
ph6 = 0 0 2 2
ph7 = 3 3 1 1
ph8 = 0 0 0 0 2 2 2 2
ph31= 0 2 2 0
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl3 : f3 channel - power level for pulse (default)
;pl10: f1 channel - power level for CP
;pl16: f3 channel - power level for CPD/BB decoupling
;pl19: f1 channel - power level for CPD/BB decoupling
;pl22: f3 channel - power level for CP
;sp1: f1 channel - shaped pulse 90 degree (H2O on resonance)
;sp2: f2 channel - shaped pulse 90 degree (Ca on resonance)
;sp3: f2 channel - shaped pulse 180 degree (Ca on resonance)
;sp5: f2 channel - shaped pulse 180 degree (C=O off resonance)
;sp8: f2 channel - shaped pulse 90 degree (Ca on resonance)
; for time reversed pulse
;sp9: f2 channel - shaped pulse 180 degree (Ca on resonance)
; sp9 requires higher selectivity - refocussing Calpha only
;p1 : f1 channel - 90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p11: f1 channel - 90 degree shaped pulse
;p13: f2 channel - 90 degree shaped pulse
;p14: f2 channel - 180 degree shaped pulse
;p16: homospoil/gradient pulse [1 msec]
;p21: f3 channel - 90 degree high power pulse
;p22: f3 channel - 180 degree high power pulse
;p24: f2 channel - 180 degree shaped pulse (Ca, selective)
;p26: f1 channel - 90 degree pulse at pl19
;d0: incremented delay (F1 in 2D) = d23/2-p14/2
;d1 : relaxation delay; 1-5 * T1
;d11: delay for disk I/O [30 msec]
;d16: delay for homospoil/gradient recovery
;d17: incremented delay (F1 in 2D) [3 usec]
;d21: 1/(2J(NH)) [5.5 msec]
;d23: 1/(4J(NCa)) [12.4 msec]
;d26: 1/(4J'(NH)) [2.3 msec]
;d27: 1/(4J`(NCa)) [12.5 msec]
;d29: incremented delay (F1 in 2D) = d23/2-p14/2-p26-d21-4u
;d30: decremented delay (F1 in 2D) = d23/2+p14/2+d17
;cnst0: amide 15N in ppm
;cnst9: CP power in Hz
;cnst19: amide 1H in ppm
;cnst21: CO chemical shift (offset, in ppm)
;o2p: Calpha chemical shift
;inf1: 1/SW(N) = 2 * DW(N)
;in0: 1/(4 * SW(N)) = (1/2) DW(N)
;nd0: 4
;in17: = (1 - k2) * in0
;in29: = in0
;in30: = k2 * in0
;ns: 8 * n
;ds: >= 8
;td1: number of experiments in F1
;FnMODE: Echo-Antiecho in F1
;cpds1: decoupling according to sequence defined by cpdprg1
;cpds3: decoupling according to sequence defined by cpdprg3
;pcpd1: f1 channel - 90 degree pulse for decoupling sequence
;pcpd3: f3 channel - 90 degree pulse for decoupling sequence
;use gradient ratio: gp 1 :gp 2 : gp 3 : gp 4 : gp 5
; 30 : 80 : 8.1 : 50 : 23
;for z-only gradients:
;gpz1: 30%
;gpz2: 80%
;gpz3: 8.1%
;gpz4: 50%
;gpz5: 23%
;use gradient files:
;gpnam1: SMSQ10.100
;gpnam2: SMSQ10.100
;gpnam3: SMSQ10.100
;gpnam4: SMSQ10.100
;gpnam5: SMSQ10.100
F1F2-selective HN(CA)NH (pseudo-3D version)¶
This pulse program is a F1F2-selective HN(CA)NH experiment to probe multiple residues as a pseudo-3D acquisition experiment.
You can download the pulse program here - f1f2hncanh3d
;f1f2hncanh3d
;
;avance-version (05/23/2017)
;pseudo-3D F1F2-selective HN(CA)NH
;2D sequence with
; inverse correlation for triple resonance using multiple
; inept transfer steps
;on/off resonance Ca and C=O pulses using shaped pulse
;phase sensitive (t1)
;phase sensitive using Echo/Antiecho-TPPI gradient selection (t1)
;using semi-constant time in t1
;acquisition as pseudo-3D
;
; F1(H) -(CP)-> F2(N) -> F3(Ca) -> F2(N,t1) -> F1(H,t2)
;
;E. Walinda, D. Morimoto, M. Shirakawa, and K. Sugase,
; J. Biomol. NMR, 2017, 68 (1), 41-52
;
;$CLASS=HighRes
;$DIM=3D
;$TYPE=
;$SUBTYPE=
;$COMMENT=
#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>
define list<frequency> fq1H=<$FQ1LIST>
define list<frequency> fq15N=<$FQ2LIST>
define pulse Pcp
"Pcp=10.8ms"
"p2=p1*2"
"p22=p21*2"
"p26=pcpd1"
"plw0=0"
"plw10=plw1*pow(p1/(250000/cnst9),2)" ; 1H CP power
"plw22=plw3*pow(p21/(250000/cnst9),2)" ; 15N CP power
"plw16=plw3*pow((p21/pcpd3),2)" ; 15N decoupling power
"plw19=plw1*pow((p1/pcpd1),2)" ; 1H decoupling power
"spw1=plw1*pow((p1/(p11*0.5889)),2)" ; Water-flip-back pulse power
"d11=30m"
"d21=5.5m"
"d23=12.4m"
"d26=2.3m"
"d27=12.5m"
"d10=d23/2-p14/2"
"d17=3u"
"d29=d23/2-p14/2-p26-d21-4u"
"d30=d23/2+p14/2+d17"
"in10=inf2/4"
"FACTOR2=d30*10000000*2/td1"
"in30=FACTOR2/10000000"
"if ( in30 > in10 ) { in17 = 0; } else { in17=in10-in30; }"
"if ( in30 > in10 ) { in30 = in10; }"
"in29=in10"
"l11=0"
"DELTA=d21-p16-d16"
"DELTA1=p16+d16+4u"
"spoff2=0"
"spoff3=0"
"spoff5=bf2*(cnst21/1000000)-o2"
"spoff8=0"
"spoff9=0"
"acqt0=0"
baseopt_echo
aqseq 312
1 ze
d11 pl16:f3
2 d11 do:f3
"fq1H.idx=(l11)"
"fq15N.idx=(l11)"
d1 pl0:f1
50u UNBLKGRAD
(p11:sp1 ph2):f1
4u
4u pl1:f1 fq1H:f1
(p1 ph0):f1
4u pl10:f1 pl22:f3 fq15N:f3
(Pcp ph1):f1 (Pcp ph0):f3 ; cross polarization
4u pl19:f1 fq=0 (sfo hz):f1 fq=0 (sfo hz):f3 pl3:f3
;*******************************************************
(p21 ph1):f3
p16:gp1
d16
(ralign (p26 ph3):f1 (p21 ph4):f3 )
d23 cpds1:f1 ph0
(center (p14:sp3 ph0):f2 (p22 ph0):f3 )
d23
(p21 ph0):f3
4u do:f1
(p26 ph1):f1
p16:gp4
d16
(p26 ph3):f1
4u cpds1:f1 ph0
;******************************************************* N -> Ca
(p13:sp2 ph0):f2
d27
(p14:sp5 ph0):f2
d27
(center (p24:sp9 ph0):f2 (p22 ph0):f3 )
d27
(p14:sp5 ph0):f2
d27
(p13:sp8 ph0):f2
;******************************************************* Ca -> N
4u do:f1
(p26 ph1):f1
p16:gp5
d16
(p26 ph3):f1
4u cpds1:f1 ph0
;******************************************************* 15N chemical shift evolution
(p21 ph5):f3
d30
(p14:sp5 ph0):f2
d30
(p22 ph8):f3
d17
(p14:sp5 ph0):f2
d17
(p14:sp3 ph0):f2
d10
(p14:sp5 ph0):f2
d29
;*******************************************************
4u do:f1
(p26 ph1):f1
p16:gp2*EA
d16
DELTA pl1:f1
;******************************************************* PEP
(center (p1 ph0):f1 (p21 ph6):f3 )
d26
(center (p2 ph0):f1 (p22 ph0):f3 )
d26
(center (p1 ph1):f1 (p21 ph7):f3 )
d26
(center (p2 ph0):f1 (p22 ph0):f3 )
d26
(p1 ph0):f1
DELTA1
(p2 ph0):f1
p16:gp3
d16 pl16:f3
4u BLKGRAD
go=2 ph31 cpd3:f3
d11 do:f3 mc #0 to 2
F1QF(calclc(l11, 1))
F2EA(calgrad(EA) & calph(ph7, +180), caldel(d10, +in10) & caldel(d17, +in17) & caldel(d29, +in29) & caldel(d30, -in30) & calph(ph5, +180) & calph(ph31, +180))
exit
ph0 = 0
ph1 = 1
ph2 = 2
ph3 = 3
ph4 = 1 3
ph5 = 0
ph6 = 0 0 2 2
ph7 = 3 3 1 1
ph8 = 0 0 0 0 2 2 2 2
ph31= 0 2 2 0
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl3 : f3 channel - power level for pulse (default)
;pl10: f1 channel - power level for CP
;pl16: f3 channel - power level for CPD/BB decoupling
;pl19: f1 channel - power level for CPD/BB decoupling
;pl22: f3 channel - power level for CP
;sp1: f1 channel - shaped pulse 90 degree (H2O on resonance)
;sp2: f2 channel - shaped pulse 90 degree (Ca on resonance)
;sp3: f2 channel - shaped pulse 180 degree (Ca on resonance)
;sp5: f2 channel - shaped pulse 180 degree (C=O off resonance)
;sp8: f2 channel - shaped pulse 90 degree (Ca on resonance)
; for time reversed pulse
;sp9: f2 channel - shaped pulse 180 degree (Ca on resonance)
; sp9 requires higher selectivity - refocussing Calpha only
;p1 : f1 channel - 90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p11: f1 channel - 90 degree shaped pulse
;p13: f2 channel - 90 degree shaped pulse
;p14: f2 channel - 180 degree shaped pulse
;p16: homospoil/gradient pulse [1 msec]
;p21: f3 channel - 90 degree high power pulse
;p22: f3 channel - 180 degree high power pulse
;p24: f2 channel - 180 degree shaped pulse (Ca, selective)
;p26: f1 channel - 90 degree pulse at pl19
;d1 : relaxation delay; 1-5 * T1
;d10: incremented delay (F2 in 2D) = d23/2-p14/2
;d11: delay for disk I/O [30 msec]
;d16: delay for homospoil/gradient recovery
;d17: incremented delay (F1 in 2D) [3 usec]
;d21: 1/(2J(NH)) [5.5 msec]
;d23: 1/(4J(NCa)) [12.4 msec]
;d26: 1/(4J'(NH)) [2.3 msec]
;d27: 1/(4J`(NCa)) [12.5 msec]
;d29: incremented delay (F1 in 2D) = d23/2-p14/2-p26-d21-4u
;d30: decremented delay (F1 in 2D) = d23/2+p14/2+d17
;cnst9: CP power in Hz
;cnst21: CO chemical shift (offset, in ppm)
;o2p: Calpha chemical shift
;inf2: 1/SW(N) = 2 * DW(N)
;in10: 1/(4 * SW(N)) = (1/2) DW(N)
;nd10: 4
;in17: = (1 - k2) * in10
;in29: = in10
;in30: = k2 * in10
;ns: 8 * n
;ds: >= 8
;td1: number of frequencies in fq-list
;td2: number of experiments in F2
;FnMODE: QF in F1
;FnMODE: Echo-Antiecho in F2
;cpds1: decoupling according to sequence defined by cpdprg1
;cpds3: decoupling according to sequence defined by cpdprg3
;pcpd1: f1 channel - 90 degree pulse for decoupling sequence
;pcpd3: f3 channel - 90 degree pulse for decoupling sequence
;use gradient ratio: gp 1 :gp 2 : gp 3 : gp 4 : gp 5
; 30 : 80 : 8.1 : 50 : 23
;for z-only gradients:
;gpz1: 30%
;gpz2: 80%
;gpz3: 8.1%
;gpz4: 50%
;gpz5: 23%
;use gradient files:
;gpnam1: SMSQ10.100
;gpnam2: SMSQ10.100
;gpnam3: SMSQ10.100
;gpnam4: SMSQ10.100
;gpnam5: SMSQ10.100
F1F2-selective NOESY-[1H, 15N]-HSQC¶
You can download the pulse program here - f1f2nNnoesygpsi
;f1f2nNnoesygpsi
;
;avance-version (05/23/2017)
;2D F1F2(1H-15N)-selective 15N NOESY-HSQC
;2D sequence with
; homonuclear correlation via dipolar coupling
; dipolar coupling may be due to noe or chemical exchange.
; H-1/X correlation via inept transfer
; using sensitivity improvement
;phase sensitive using Echo/Antiecho-TPPI gradient selection (t1)
;with decoupling during acquisition
;using trim pulses in inept transfer
;using f3 - channel
;
; F1(H) -(CP)-> F2(N) -> -(CP)-> F1(H) -(NOE)-> F1(H) -> F2(N,t1) -> F1(H,t2)
;
;E. Walinda, D. Morimoto, M. Shirakawa, and K. Sugase,
; J. Biomol. NMR, 2017, 68 (1), 41-52
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=
#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>
define pulse Pcp
"Pcp=10.8ms"
"p2=p1*2"
"p22=p21*2"
"plw0=0"
"plw10=plw1*pow(p1/(250000/cnst9),2)" ; 1H CP power
"plw22=plw3*pow(p21/(250000/cnst9),2)" ; 15N CP power
"plw16=plw3*pow((p21/pcpd3),2)" ; 15N decoupling power
"spw1=plw1*pow((p1/(p11*0.5889)),2)" ; Water-flip-back pulse power
"cnst5=sfo1*cnst19-o1*1000000"
"cnst6=sfo3*cnst0-o3*1000000"
"d0=3u"
"d11=30m"
"d26=1s/(cnst4*4)"
"in0=inf1/2"
"DELTA=d8-p16-d16"
# ifdef LABEL_CN
"DELTA1=p16+d16+larger(p2,p8)+d0*2"
"spw13=plw2*pow((p3/((p8/2)*0.1023327)),2)" ; 13C 180 adiabatic pulse power
# else
"DELTA1=p16+d16+p2+d0*2"
# endif /*LABEL_CN*/
"DELTA2=d26-p19-d16"
"DELTA3=d26-p16-d16"
"DELTA4=p16+d16+4u"
"acqt0=0"
baseopt_echo
1 ze
d11 pl16:f3
2 d11 do:f3
3 d1 pl0:f1
50u UNBLKGRAD
(p11:sp1 ph2):f1
4u
4u pl1:f1 fq=cnst5 (sfo hz):f1
(p1 ph0):f1
4u pl10:f1 pl22:f3 fq=cnst6 (sfo hz):f3
(Pcp ph1):f1 (Pcp ph0):f3 ; cross polarization
4u pl3:f3
(p21 ph1):f3
p16:gp6
d16
(p21 ph3):f3
4u pl22:f3
(Pcp ph7):f1 (Pcp ph8):f3 ; cross polarization
4u pl1:f1 fq=0 (sfo hz):f1 fq=0 (sfo hz):f3 pl3:f3
;*******************************************************
(p1 ph1):f1
DELTA
p16:gp7
d16
(p1 ph0):f1
d26
(center (p2 ph0):f1 (p22 ph0):f3 )
d26
(p1 ph1):f1
p16:gp1
d16
(p21 ph5):f3
;******************************************************* 15N chemical shift evolution
d0
# ifdef LABEL_CN
(center (p2 ph0):f1 (p8:sp13 ph0):f2 )
# else
(p2 ph0):f1
# endif /*LABEL_CN*/
d0
;******************************************************* PEP
p16:gp2*EA
d16
(p22 ph0):f3
DELTA1
(center (p1 ph0):f1 (p21 ph0):f3 )
p19:gp4
d16
DELTA2
(center (p2 ph0):f1 (p22 ph0):f3 )
DELTA2
p19:gp4
d16
(center (p1 ph1):f1 (p21 ph4):f3 )
p16:gp5
d16
DELTA3
(center (p2 ph0):f1 (p22 ph0):f3 )
DELTA3
p16:gp5
d16
(p1 ph0):f1
DELTA4
(p2 ph0):f1
p16:gp3
d16 pl16:f3
4u BLKGRAD
go=2 ph31 cpd3:f3
d1 do:f3 mc #0 to 3
F1EA(calgrad(EA) & calph(ph4, +180), caldel(d0, +in0) & calph(ph5, +180) & calph(ph31, +180))
exit
ph0 = 0
ph1 = 1
ph2 = 2
ph3 = 3
ph4 = 1 1 1 1 3 3 3 3
ph5 = 0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2
ph7 = 0 2
ph8 = 0 0 2 2
ph31= 0 2 2 0 2 0 0 2 2 0 0 2 0 2 2 0
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl3 : f3 channel - power level for pulse (default)
;pl10: f1 channel - power level for CP
;pl16: f3 channel - power level for CPD/BB decoupling
;pl22: f3 channel - power level for CP
;sp1: f1 channel - shaped pulse 90 degree
;spnam1: Sinc1.1000
;sp13: f2 channel - shaped pulse 180 degree (adiabatic)
;spnam13: Crp60,0.5,20.1
;p1 : f1 channel - 90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel - 90 degree high power pulse
;p8 : f2 channel - 180 degree shaped pulse for inversion (adiabatic)
;p11: f1 channel - 90 degree shaped pulse
;p16: homospoil/gradient pulse [1 msec]
;p19: gradient pulse 2 [500 usec]
;p21: f3 channel - 90 degree high power pulse
;p22: f3 channel - 180 degree high power pulse
;d0 : incremented delay (F1 in 2D) [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d8 : mixing time
;d11: delay for disk I/O [30 msec]
;d16: delay for homospoil/gradient recovery
;d26: 1/(4J(NH))
;cnst0: amide 15N in ppm
;cnst4: = J(NH)
;cnst9: CP power in Hz
;cnst19: amide 1H in ppm
;inf1: 1/SW(N) = 2 * DW(N)
;in0: 1/(2 * SW(N)) = DW(N)
;nd0: 2
;ns: 8 * n
;ds: >= 16
;td1: number of experiments in F1
;FnMODE: Echo-Antiecho in F1
;cpd3: decoupling according to sequence defined by cpdprg3
;pcpd3: f3 channel - 90 degree pulse for decoupling sequence
;use gradient ratio: gp 1 : gp 2 : gp 3 : gp 4 : gp 5 : gp 6 : gp 7
; 30 : 80 : 8.1 : 5 : -2 : 6 : 50
;for z-only gradients:
;gpz1: 30%
;gpz2: 80%
;gpz3: 8.1%
;gpz4: 5%
;gpz5: -2%
;gpz6: 6%
;gpz7: 50%
;use gradient files:
;gpnam1: SMSQ10.100
;gpnam2: SMSQ10.100
;gpnam3: SMSQ10.100
;gpnam4: SMSQ10.50
;gpnam5: SMSQ10.100
;gpnam6: SMSQ10.100
;gpnam7: SMSQ10.100
;preprocessor-flags-start
;LABEL_CN: for C-13 and N-15 labeled samples start experiment with
; option -DLABEL_CN (eda: ZGOPTNS)
;preprocessor-flags-end
F1F2-selective NOESY-[1H, 15N]-HSQC (pseudo-3D version)¶
You can download the pulse program here - f1f2nNnoesygpsi3d
;f1f2nNnoesygpsi3d.2
;
;avance-version (05/23/2017)
;F1F2(1H-15N)-selective 15N NOESY-HSQC
;2D sequence with
; homonuclear correlation via dipolar coupling
; dipolar coupling may be due to noe or chemical exchange.
; H-1/X correlation via inept transfer
; using sensitivity improvement
;phase sensitive using Echo/Antiecho-TPPI gradient selection (t1)
;with decoupling during acquisition
;using trim pulses in inept transfer
;using f3 - channel
;acquisition as pseudo-3D
;
; F1(H) -(CP)-> F2(N) -> -(CP)-> F1(H) -(NOE)-> F1(H) -> F2(N,t1) -> F1(H,t2)
;
;E. Walinda, D. Morimoto, M. Shirakawa, and K. Sugase,
; J. Biomol. NMR, 2017, 68 (1), 41-52
;
;$CLASS=HighRes
;$DIM=3D
;$TYPE=
;$SUBTYPE=
;$COMMENT=
#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>
define list<frequency> fq1H=<$FQ1LIST>
define list<frequency> fq15N=<$FQ2LIST>
define pulse Pcp
"Pcp=10.8ms"
"p2=p1*2"
"p22=p21*2"
"plw0=0"
"plw10=plw1*pow(p1/(250000/cnst9),2)" ; 1H CP power
"plw22=plw3*pow(p21/(250000/cnst9),2)" ; 15N CP power
"plw16=plw3*pow((p21/pcpd3),2)" ; 15N decoupling power
"spw1=plw1*pow((p1/(p11*0.5889)),2)" ; Water-flip-back pulse power
"d10=3u"
"d11=30m"
"d26=1s/(cnst4*4)"
"in10=inf2/2"
"DELTA=d8-p16-d16"
# ifdef LABEL_CN
"DELTA1=p16+d16+larger(p2,p8)+d10*2"
"spw13=plw2*pow((p3/((p8/2)*0.1023327)),2)" ; 13C 180 adiabatic pulse power
# else
"DELTA1=p16+d16+p2+d10*2"
# endif /*LABEL_CN*/
"DELTA2=d26-p19-d16"
"DELTA3=d26-p16-d16"
"DELTA4=p16+d16+4u"
"acqt0=0"
baseopt_echo
aqseq 312
1 ze
d11 pl16:f3 st0
2 6m
3 6m
4 d11 do:f3
d1 pl0:f1
50u UNBLKGRAD
(p11:sp1 ph2):f1
4u
4u pl1:f1 fq1H:f1
(p1 ph0):f1
4u pl10:f1 pl22:f3 fq15N:f3
(Pcp ph1):f1 (Pcp ph0):f3 ; cross polarization
4u pl3:f3
(p21 ph1):f3
p16:gp6
d16
(p21 ph3):f3
4u pl22:f3
(Pcp ph7):f1 (Pcp ph8):f3 ; cross polarization
4u pl1:f1 fq=0 (sfo hz):f1 fq=0 (sfo hz):f3 pl3:f3
;*******************************************************
(p1 ph1):f1
DELTA
p16:gp7
d16
(p1 ph0):f1
d26
(center (p2 ph0):f1 (p22 ph0):f3 )
d26
(p1 ph1):f1
p16:gp1
d16
(p21 ph5):f3
;******************************************************* 15N chemical shift evolution
d10
# ifdef LABEL_CN
(center (p2 ph0):f1 (p8:sp13 ph0):f2 )
# else
(p2 ph0):f1
# endif /*LABEL_CN*/
d10
;*******************************************************
p16:gp2*EA
d16
(p22 ph0):f3
DELTA1
(center (p1 ph0):f1 (p21 ph0):f3 )
p19:gp4
d16
DELTA2
(center (p2 ph0):f1 (p22 ph0):f3 )
DELTA2
p19:gp4
d16
(center (p1 ph1):f1 (p21 ph4):f3 )
p16:gp5
d16
DELTA3
(center (p2 ph0):f1 (p22 ph0):f3 )
DELTA3
p16:gp5
d16
(p1 ph0):f1
DELTA4
(p2 ph0):f1
p16:gp3
d16 pl16:f3
4u BLKGRAD
goscnp ph31 cpd3:f3
3m do:f3
3m st fq1H.inc fq15N.inc
lo to 3 times nbl
3m fq1H.res fq15N.res
3m ipp4 ipp5 ipp7 ipp8 ipp31
lo to 4 times ns
d11 mc #0 to 4
F1QF()
F2EA(calgrad(EA) & calph(ph4, +180) & exec(rppall), caldel(d10, +in10) & calph(ph5, +180) & calph(ph31, +180))
exit
ph0 = 0
ph1 = 1
ph2 = 2
ph3 = 3
ph4 = 1 1 1 1 3 3 3 3
ph5 = 0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2
ph7 = 0 2
ph8 = 0 0 2 2
ph31= 0 2 2 0 2 0 0 2 2 0 0 2 0 2 2 0
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl3 : f3 channel - power level for pulse (default)
;pl10: f1 channel - power level for CP
;pl16: f3 channel - power level for CPD/BB decoupling
;pl22: f3 channel - power level for CP
;sp1: f1 channel - shaped pulse 90 degree
;spnam1: Sinc1.1000
;sp13: f2 channel - shaped pulse 180 degree (adiabatic)
;spnam13: Crp60,0.5,20.1
;p1 : f1 channel - 90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel - 90 degree high power pulse
;p8 : f2 channel - 180 degree shaped pulse for inversion (adiabatic)
;p11: f1 channel - 90 degree shaped pulse
;p16: homospoil/gradient pulse [1 msec]
;p19: gradient pulse 2 [500 usec]
;p21: f3 channel - 90 degree high power pulse
;p22: f3 channel - 180 degree high power pulse
;d1 : relaxation delay; 1-5 * T1
;d8 : mixing time
;d10: incremented delay (F1 in 2D) [3 usec]
;d11: delay for disk I/O [30 msec]
;d16: delay for homospoil/gradient recovery
;d26: 1/(4J(YH))
;cnst4: = J(YH)
;cnst9: CP power in Hz
;inf2: 1/SW(X) = 2 * DW(X)
;in10: 1/(2 * SW(X)) = DW(X)
;nd10: 2
;ns: 8 * n
;ds: >= 16
;td1: number of frequencies in fq-list
;td2: number of experiments in F2
;FnMODE: QF in F1
;FnMODE: Echo-Antiecho in F2
;cpd3: decoupling according to sequence defined by cpdprg3
;pcpd3: f3 channel - 90 degree pulse for decoupling sequence
;use gradient ratio: gp 1 : gp 2 : gp 3 : gp 4 : gp 5 : gp 6 : gp 7
; 30 : 80 : 8.1 : 5 : -2 : 6 : 50
;for z-only gradients:
;gpz1: 30%
;gpz2: 80%
;gpz3: 8.1%
;gpz4: 5%
;gpz5: -2%
;gpz6: 6%
;gpz7: 50%
;use gradient files:
;gpnam1: SMSQ10.100
;gpnam2: SMSQ10.100
;gpnam3: SMSQ10.100
;gpnam4: SMSQ10.50
;gpnam5: SMSQ10.100
;gpnam6: SMSQ10.100
;gpnam7: SMSQ10.100
;preprocessor-flags-start
;LABEL_CN: for C-13 and N-15 labeled samples start experiment with
; option -DLABEL_CN (eda: ZGOPTNS)
;preprocessor-flags-end
F1F2-selective NOESY-[1H, 13C]-HSQC¶
You can download the pulse program here - f1f2nCnoesygp
;f1f2nCnoesygp
;
;avance-version (05/23/2017)
;2D F1F2(1H-15N)-selective 13C NOESY-HSQC
;2D sequence with
; homonuclear correlation via dipolar coupling
; dipolar coupling may be due to noe or chemical exchange.
; H-1/X correlation via inept transfer
;phase sensitive using Echo/Antiecho-TPPI gradient selection (t1)
;with decoupling during acquisition
;
; F1(H) -(CP)-> F2(N) -> -(CP)-> F1(H) -(NOE)-> F1(H) -> F2(N,t1) -> F1(H,t2)
;
;E. Walinda, D. Morimoto, M. Shirakawa, and K. Sugase,
; J. Biomol. NMR, 2017, 68 (1), 41-52
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=
#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>
define pulse Pcp
"Pcp=10.8ms"
"p2=p1*2"
"p22=p21*2"
"plw0=0"
"plw10=plw1*pow(p1/(250000/cnst9),2)" ; 1H CP power
"plw22=plw3*pow(p21/(250000/cnst9),2)" ; 15N CP power
"plw12=plw2*pow((p3/pcpd2),2)" ; 13C decoupling power
"spw1=plw1*pow((p1/(p11*0.5889)),2)" ; Water-flip-back pulse power
"spw7=plw2*pow((p3/((p24/2)*0.02558317)),2)" ; 13C 180 adiabatic pulse power
"spw13=plw2*pow((p3/((p8/2)*0.1023327)),2)" ; 13C 180 adiabatic pulse power
"cnst5=sfo1*cnst19-o1*1000000"
"cnst6=sfo3*cnst0-o3*1000000"
"d0=3u"
"d11=30m"
"d4=1s/(cnst2*4)"
"in0=inf1/2"
"DELTA=d8-p16-d16"
# ifdef LABEL_CN
"DELTA1=p16+d16+larger(p2,p22)+d0*2"
# else
"DELTA1=p16+d16+p2+d0*2"
# endif /*LABEL_CN*/
"DELTA2=d4-larger(p2,p8)/2"
"DELTA3=d4-p16-larger(p2,p8)/2-4u"
"acqt0=0"
baseopt_echo
1 ze
d11 pl12:f2
2 d11 do:f2
3 d1 pl0:f1
50u UNBLKGRAD
(p11:sp1 ph2):f1
4u
4u pl1:f1 fq=cnst5 (sfo hz):f1
(p1 ph0):f1
4u pl10:f1 pl22:f3 fq=cnst6 (sfo hz):f3
(Pcp ph1):f1 (Pcp ph0):f3 ; cross polarization
4u pl3:f3
(p21 ph1):f3
p16:gp6
d16
(p21 ph3):f3
4u pl22:f3
(Pcp ph7):f1 (Pcp ph8):f3 ; cross polarization
4u pl1:f1 fq=0 (sfo hz):f1 fq=0 (sfo hz):f3 pl2:f2
;*******************************************************
(p1 ph1):f1
DELTA
p16:gp7
d16
(p1 ph0):f1
DELTA2 pl0:f2
(center (p2 ph0):f1 (p8:sp13 ph6):f2 )
DELTA2
(p28 ph0):f1
4u pl2:f2
(p1 ph1):f1 (p3 ph5):f2
;******************************************************* 13C chemical shift evolution
d0
# ifdef LABEL_CN
(center (p2 ph0):f1 (p22 ph0):f3 )
# else
(p2 ph0):f1
# endif /*LABEL_CN*/
d0
;******************************************************* reverse INEPT
p16:gp2*EA
d16 pl0:f2
4u
(p24:sp7 ph4):f2
4u
DELTA1 pl2:f2
(ralign (p1 ph0):f1 (p3 ph4):f2 )
DELTA2 pl0:f2
(center (p2 ph0):f1 (p8:sp13 ph0):f2 )
p16:gp3
DELTA3 pl12:f2
4u BLKGRAD
go=2 ph31 cpd2:f2
d1 do:f2 mc #0 to 3
F1EA(calgrad(EA), caldel(d0, +in0) & calph(ph5, +180) & calph(ph6, +180) & calph(ph31, +180))
exit
ph0 = 0
ph1 = 1
ph2 = 2
ph3 = 3
ph4 = 0 0 0 0 2 2 2 2
ph5 = 0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2
ph6 = 0
ph7 = 0 2
ph8 = 0 0 2 2
ph31= 0 2 2 0 2 0 0 2 2 0 0 2 0 2 2 0
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl3 : f3 channel - power level for pulse (default)
;pl10: f1 channel - power level for CP
;pl12: f2 channel - power level for CPD/BB decoupling
;pl22: f3 channel - power level for CP
;sp1: f1 channel - shaped pulse 90 degree
;spnam1: Sinc1.1000
;sp7: f2 channel - shaped pulse 180 degree for refocussing
;spnam7: Crp60comp.4
;sp13 : f2 channel - shaped pulse 180 degree (adiabatic)
;spnam13: Crp60,0.5,20.1
;p1 : f1 channel - 90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel - 90 degree high power pulse
;p8 : f2 channel - 180 degree shaped pulse for inversion (adiabatic)
; 500 usec Crp60,0.5,20.1
;p11: f1 channel - 90 degree shaped pulse
;p16: homospoil/gradient pulse [1 msec]
;p21: f3 channel - 90 degree high power pulse
;p22: f3 channel - 180 degree high power pulse
;p24: f2 channel - 180 degree shaped pulse for refocussing
; 2 msec Crp60comp.4
;p28: f1 channel - trim pulse
;d0 : incremented delay (F1 in 2D) [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d4 : 1/(4J(YH))
;d8 : mixing time
;d11: delay for disk I/O [30 msec]
;d16: delay for homospoil/gradient recovery
;cnst0: amide 15N in ppm
;cnst2: = J(CH)
;cnst9: CP power in Hz
;cnst19: amide 1H in ppm
;inf1: 1/SW(C) = 2 * DW(C)
;in0: 1/(2 * SW(C)) = DW(C)
;nd0: 2
;ns: 8 * n
;ds: >= 16
;td1: number of experiments in F1
;FnMODE: Echo-Antiecho in F1
;cpd2: decoupling according to sequence defined by cpdprg2
;pcpd2: f2 channel - 90 degree pulse for decoupling sequence
;use gradient ratio: gp 2 : gp 3 : gp 6 : gp 7
; 80 : 20.1 : 6 : 50
;for z-only gradients:
;gpz2: 80%
;gpz3: 20.1%
;gpz6: 6%
;gpz7: 50%
;use gradient files:
;gpnam2: SMSQ10.100
;gpnam3: SMSQ10.100
;gpnam6: SMSQ10.100
;gpnam7: SMSQ10.100
;preprocessor-flags-start
;LABEL_CN: for C-13 and N-15 labeled samples start experiment with
; option -DLABEL_CN (eda: ZGOPTNS)
;preprocessor-flags-end
F1F2-selective NOESY-[1H, 13C]-HSQC (pseudo-3D version)¶
You can download the pulse program here - f1f2nCnoesygp
;f1f2nCnoesygp3d
;
;avance-version (05/23/2017)
;2D F1F2(1H-15N)-selective 13C NOESY-HSQC
;2D sequence with
; homonuclear correlation via dipolar coupling
; dipolar coupling may be due to noe or chemical exchange.
; H-1/X correlation via inept transfer
;phase sensitive using Echo/Antiecho-TPPI gradient selection (t1)
;with decoupling during acquisition
;acquisition as pseudo-3D
;
; F1(H) -(CP)-> F2(N) -> -(CP)-> F1(H) -(NOE)-> F1(H) -> F2(N,t1) -> F1(H,t2)
;
;E. Walinda, D. Morimoto, M. Shirakawa, and K. Sugase,
; J. Biomol. NMR, 2017, 68 (1), 41-52
;
;$CLASS=HighRes
;$DIM=3D
;$TYPE=
;$SUBTYPE=
;$COMMENT=
#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>
define list<frequency> fq1H=<$FQ1LIST>
define list<frequency> fq15N=<$FQ2LIST>
define pulse Pcp
"Pcp=10.8ms"
"p2=p1*2"
"p22=p21*2"
"plw0=0"
"plw10=plw1*pow(p1/(250000/cnst9),2)" ; 1H CP power
"plw22=plw3*pow(p21/(250000/cnst9),2)" ; 15N CP power
"plw12=plw2*pow((p3/pcpd2),2)" ; 13C decoupling power
"spw1=plw1*pow((p1/(p11*0.5889)),2)" ; Water-flip-back pulse power
"spw7=plw2*pow((p3/((p24/2)*0.02558317)),2)" ; 13C 180 adiabatic pulse power
"spw13=plw2*pow((p3/((p8/2)*0.1023327)),2)" ; 13C 180 adiabatic pulse power
"d10=3u"
"d11=30m"
"d4=1s/(cnst2*4)"
"in10=inf2/2"
"l11=0"
"DELTA=d8-p16-d16"
# ifdef LABEL_CN
"DELTA1=p16+d16+larger(p2,p22)+d10*2"
# else
"DELTA1=p16+d16+p2+d10*2"
# endif /*LABEL_CN*/
"DELTA2=d4-larger(p2,p8)/2"
"DELTA3=d4-p16-larger(p2,p8)/2-4u"
"acqt0=0"
baseopt_echo
aqseq 312
1 ze
d11 pl12:f2
2 d11 do:f2
"fq1H.idx=(l11)"
"fq15N.idx=(l11)"
d1 pl0:f1
50u UNBLKGRAD
(p11:sp1 ph2):f1
4u
4u pl1:f1 fq1H:f1
(p1 ph0):f1
4u pl10:f1 pl22:f3 fq15N:f3
(Pcp ph1):f1 (Pcp ph0):f3 ; cross polarization
4u pl3:f3
(p21 ph1):f3
p16:gp6
d16
(p21 ph3):f3
4u pl22:f3
(Pcp ph7):f1 (Pcp ph8):f3 ; cross polarization
4u pl1:f1 fq=0 (sfo hz):f1 fq=0 (sfo hz):f3 pl2:f2
;*******************************************************
(p1 ph1):f1
DELTA
p16:gp7
d16
(p1 ph0):f1
DELTA2 pl0:f2
(center (p2 ph0):f1 (p8:sp13 ph6):f2 )
DELTA2
(p28 ph0):f1
4u pl2:f2
(p1 ph1):f1 (p3 ph5):f2
;******************************************************* 13C chemical shift evolution
d10
# ifdef LABEL_CN
(center (p2 ph0):f1 (p22 ph0):f3 )
# else
(p2 ph0):f1
# endif /*LABEL_CN*/
d10
;******************************************************* reverse INEPT
p16:gp2*EA
d16 pl0:f2
4u
(p24:sp7 ph4):f2
4u
DELTA1 pl2:f2
(ralign (p1 ph0):f1 (p3 ph4):f2 )
DELTA2 pl0:f2
(center (p2 ph0):f1 (p8:sp13 ph0):f2 )
p16:gp3
DELTA3 pl12:f2
4u BLKGRAD
go=2 ph31 cpd2:f2
d11 do:f2 mc #0 to 2
F1QF(calclc(l11, 1))
F2EA(calgrad(EA), caldel(d10, +in10) & calph(ph5, +180) & calph(ph6, +180) & calph(ph31, +180))
exit
ph0 = 0
ph1 = 1
ph2 = 2
ph3 = 3
ph4 = 0 0 0 0 2 2 2 2
ph5 = 0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2
ph6 = 0
ph7 = 0 2
ph8 = 0 0 2 2
ph31= 0 2 2 0 2 0 0 2 2 0 0 2 0 2 2 0
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl3 : f3 channel - power level for pulse (default)
;pl10: f1 channel - power level for CP
;pl12: f2 channel - power level for CPD/BB decoupling
;pl22: f3 channel - power level for CP
;sp1: f1 channel - shaped pulse 90 degree
;spnam1: Sinc1.1000
;sp7: f2 channel - shaped pulse 180 degree for refocussing
;spnam7: Crp60comp.4
;sp13 : f2 channel - shaped pulse 180 degree (adiabatic)
;spnam13: Crp60,0.5,20.1
;p1 : f1 channel - 90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel - 90 degree high power pulse
;p8 : f2 channel - 180 degree shaped pulse for inversion (adiabatic)
; 500 usec Crp60,0.5,20.1
;p11: f1 channel - 90 degree shaped pulse
;p16: homospoil/gradient pulse [1 msec]
;p21: f3 channel - 90 degree high power pulse
;p22: f3 channel - 180 degree high power pulse
;p24: f2 channel - 180 degree shaped pulse for refocussing
; 2 msec Crp60comp.4
;p28: f1 channel - trim pulse
;d1 : relaxation delay; 1-5 * T1
;d4 : 1/(4J(YH))
;d8 : mixing time
;d10 : incremented delay (F1 in 2D) [3 usec]
;d11: delay for disk I/O [30 msec]
;d16: delay for homospoil/gradient recovery
;cnst2: = J(CH)
;cnst9: CP power in Hz
;inf2: 1/SW(C) = 2 * DW(C)
;in10: 1/(2 * SW(C)) = DW(C)
;nd10: 2
;ns: 8 * n
;ds: >= 16
;td1: number of frequencies in fq-list
;td2: number of experiments in F2
;FnMODE: QF in F1
;FnMODE: Echo-Antiecho in F2
;cpd2: decoupling according to sequence defined by cpdprg2
;pcpd2: f2 channel - 90 degree pulse for decoupling sequence
;use gradient ratio: gp 2 : gp 3 : gp 6 : gp 7
; 80 : 20.1 : 6 : 50
;for z-only gradients:
;gpz2: 80%
;gpz3: 20.1%
;gpz6: 6%
;gpz7: 50%
;use gradient files:
;gpnam2: SMSQ10.100
;gpnam3: SMSQ10.100
;gpnam6: SMSQ10.100
;gpnam7: SMSQ10.100
;preprocessor-flags-start
;LABEL_CN: for C-13 and N-15 labeled samples start experiment with
; option -DLABEL_CN (eda: ZGOPTNS)
;preprocessor-flags-end
F1F2-selective [15N]-R1ρ relaxation dispersion¶
You can download the pulse program here - f1f2Nr1rho
;f1f2Nr1rho
;
;avance-version (05/23/2017)
;2D F1F2(1H-15N)-selective N15 R1rho relaxation dispersion
; using sensitivity improvement
;phase sensitive using Echo/Antiecho-TPPI gradient selection (t1)
;with decoupling during acquisition
;using f3 - channel
;
; F1(H) -(CP)-> F2(N) -> spin-lock(N) -> F2(N,t1) -> F1(H,t2)
;
;E. Walinda, D. Morimoto, M. Shirakawa, and K. Sugase,
; J. Biomol. NMR, 2017, 68 (1), 41-52
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=
#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>
define pulse Pcp
define delay Teq
"Pcp=10.8ms"
"Teq=5m"
"cnst2=3900" ; 1H decoupling power [Hz]
"p2=p1*2"
"p5=(PI/2-atan(abs(cnst19-o1/bf1)*bf1/cnst2))*p1/(PI/2)"
"p22=p21*2"
"plw0=0"
"plw10=plw1*pow(p1/(250000/cnst9),2)" ; 1H CP power
"plw22=plw3*pow(p21/(250000/cnst9),2)" ; 15N CP power
"plw19=plw1*pow(p1/(250000/cnst2),2)" ; 1H decoupling power
"plw16=plw3*pow((p21/pcpd3),2)" ; 15N decoupling power
"cnst10=250000/p21*sqrt(plw3/plw25)"
"plw26=plw3*pow(p21/(250000/(cnst11-cnst10)),2)"; 15N heating compensation
"spw1=plw1*pow((p1/(p11*0.5889)),2)" ; Water-flip-back pulse power
"cnst5=bf1*cnst19-o1*1000000"
"d0=3u"
"d11=30m"
"d25=p25"
"d26=1s/(cnst4*4)"
"in0=inf1/2"
"DELTA=d26-p16-d16"
# ifdef LABEL_CN
"DELTA1=d26-p16-d16-larger(p2,p8)-d0*2-8u"
"spw13=plw2*pow((p3/((p8/2)*0.1023327)),2)" ; 13C 180 adiabatic pulse power
# else
"DELTA1=d26-p16-d16-p2-d0*2-8u"
# endif /*LABEL_CN*/
"DELTA2=d26-p19-d16"
"DELTA3=d26-p16-d16"
"DELTA4=p16+d16+4u"
"DELTA5=Teq-p16-d16-p5-8u"
"acqt0=0"
baseopt_echo
1 ze
d11 pl16:f3
2 d11 do:f3
d1 pl19:f1 fq=300 (bf ppm):f1 pl3:f3
;******************************************************* 1H & 15N heating compensation
if "l0==0"
{
4u cw:f1
}
else
{
4u
}
(p21 ph3):f3
4u pl26:f3
(p25 ph0):f3
4u do:f1
;******************************************************* end heating compensation
50u UNBLKGRAD
p16:gp6
d16 pl0:f1 fq=0 (sfo hz):f1
(p11:sp1 ph2):f1
4u
4u pl1:f1 fq=cnst5 (sfo hz):f1
(p1 ph0):f1
4u pl10:f1 pl22:f3
(Pcp ph7):f1 (Pcp ph8):f3 ; cross polarization
4u pl1:f1 pl3:f3
(p21 ph1):f3
p16:gp1
d16
(p5 ph1):f1
4u pl19:f1
4u cw:f1 ph0
DELTA5
(p23 ph1):f3
;******************************************************* Begin spinlock
4u pl25:f3
if "l0==0" goto 5
(p25 ph0):f3
;******************************************************* End spinlock
5 4u pl3:f3
(p23 ph3):f3
DELTA5
4u do:f1
4u pl1:f1
(p5 ph3):f1
p16:gp7
d16 fq=0 (sfo hz):f1
(p21 ph5):f3
;******************************************************* 15N chemical shift evolution + INEPT
p16:gp2*-1*EA
d16 pl1:f1
DELTA
(p22 ph4):f3
d0 gron0
4u groff
# ifdef LABEL_CN
(center (p2 ph0):f1 (p8:sp13 ph0):f2 )
# else
(p2 ph0):f1
# endif /*LABEL_CN*/
d0 gron0*-1
4u groff
p16:gp2*EA
d16
DELTA1
;******************************************************* PEP
(center (p1 ph2):f1 (p21 ph0):f3 )
p19:gp4
d16
DELTA2
(center (p2 ph3):f1 (p22 ph0):f3 )
DELTA2
p19:gp4
d16
(center (p1 ph3):f1 (p21 ph6):f3 )
p16:gp5
d16
DELTA3
(center (p2 ph3):f1 (p22 ph3):f3 )
DELTA3
p16:gp5
d16
(p1 ph0):f1
DELTA4
(p2 ph0):f1
p16:gp3
d16 pl16:f3
4u BLKGRAD
go=2 ph31 cpds3:f3
d11 do:f3 mc #0 to 2
F1EA(calgrad(EA) & calph(ph6, +180), caldel(d0, +in0) & calph(ph5, +180) & calph(ph31, +180))
exit
ph0 = 0
ph1 = 1
ph2 = 2
ph3 = 3
ph4 = 0 0 0 0 2 2 2 2
ph5 = 1
ph6 = 3
ph7 = 1 3
ph8 = 0 0 2 2
ph31= 0 2 2 0
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl3 : f3 channel - power level for pulse (default)
;pl10: f1 channel - power level for CP
;pl16: f3 channel - power level for CPD/BB decoupling
;pl19: f1 channel - power level for CPD/BB decoupling
;pl22: f3 channel - power level for CP
;pl25: f3 channel - power level for R1rho spinlock (valist)
;pl26: f3 channel - power level for heat compensation (valist)
;sp1: f1 channel - shaped pulse 90 degree
;spnam1: Sinc1.1000
;sp13: f2 channel - shaped pulse 180 degree (adiabatic)
;spnam13: Crp60,0.5,20.1
;p1 : f1 channel - 90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel - 90 degree high power pulse
;p5 : f1 channel - X degree high power pulse
;p8 : f2 channel - 180 degree shaped pulse for inversion (adiabatic)
;p11: f1 channel - 90 degree selective pulse
;p16: homospoil/gradient pulse [1 msec]
;p19: gradient pulse 2 [500 usec]
;p21: f3 channel - 90 degree high power pulse
;p22: f3 channel - 180 degree high power pulse
;p23: f3 channel - X degree high power pulse
;p25: f3 channel - R1rho spinlock length
;d1 : relaxation delay; 1-5 * T1
;d11: delay for disk I/O [30 msec]
;d16: delay for homospoil/gradient recovery
;d26: 1/(4J(YH))
;l0: 0 for reference, non 0 for spin lock
;cnst4: = J(YH)
;cnst9: CP power in Hz
;cnst10: spin-lock power in Hz
;cnst11: highest spin-lock power in Hz
;cnst19: amide 1H in ppm
;o3p: amide 15N in ppm
;inf1: 1/SW(X) = 2 * DW(X)
;in0: 1/(2 * SW(X)) = DW(X)
;nd0: 2
;ns: 4 * n
;ds: >= 16
;td1: number of experiments in F1
;FnMODE: Echo-Antiecho in F1
;cpd3: decoupling according to sequence defined by cpdprg3
;pcpd3: f3 channel - 90 degree pulse for decoupling sequence
;use gradient ratio: gp 0 :gp 1 : gp 2 : gp 3 : gp 4 : gp 5 : gp 6 : gp 7
; 0.2 : 30 : 80 : 16.2 : 5 : -2 : 6 : -60
;for z-only gradients:
;gpz0: 0.2%
;gpz1: 30%
;gpz2: 80%
;gpz3:16.2%
;gpz4: 5%
;gpz5: -2%
;gpz6: 6%
;gpz7: -60%
;use gradient files:
;gpnam1: SMSQ10.100
;gpnam2: SMSQ10.100
;gpnam3: SMSQ10.100
;gpnam4: SMSQ10.50
;gpnam5: SMSQ10.100
;gpnam6: SMSQ10.100
;gpnam7: SMSQ10.100
;preprocessor-flags-start
;LABEL_CN: for C-13 and N-15 labeled samples start experiment with
; option -DLABEL_CN (eda: ZGOPTNS)
;preprocessor-flags-end
F1F2-selective [15N]-R1ρ relaxation dispersion (pseudo-3D version)¶
You can download the pulse program here - f1f2Nr1rho3d
;f1f2Nr1rho3d
;
;avance-version (05/23/2017)
;pseudo-3D F1F2(1H-15N)-selective N15 R1rho relaxation dispersion
; using sensitivity improvement
;phase sensitive using Echo/Antiecho-TPPI gradient selection (t1)
;with decoupling during acquisition
;using f3 - channel
;acquisition as pseudo-3D
;
; F1(H) -(CP)-> F2(N) -> spin-lock(N) -> F2(N,t1) -> F1(H,t2)
;
;E. Walinda, D. Morimoto, M. Shirakawa, and K. Sugase,
; J. Biomol. NMR, 2017, 68 (1), 41-52
;
;$CLASS=HighRes
;$DIM=3D
;$TYPE=
;$SUBTYPE=
;$COMMENT=
;
;ignore the warning regarding va15N
#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>
define list<power> va15N=<$VALIST>
define pulse Pcp
define delay Teq
"Pcp=10.8ms"
"Teq=5m"
"cnst2=3900" ; 1H decoupling power [Hz]
"p2=p1*2"
"p5=(PI/2-atan(abs(cnst19-o1/bf1)*bf1/cnst2))*p1/(PI/2)"
"p22=p21*2"
"plw0=0"
"plw10=plw1*pow(p1/(250000/cnst9),2)" ; 1H CP power
"plw22=plw3*pow(p21/(250000/cnst9),2)" ; 15N CP power
"plw19=plw1*pow(p1/(250000/cnst2),2)" ; 1H decoupling power
"plw16=plw3*pow((p21/pcpd3),2)" ; 15N decoupling power
;"cnst10=250000/p21*sqrt(plw3/plw25)"
;"plw26=plw3*pow(p21/(250000/(cnst11-cnst10)),2)"; 15N heating compensation
"spw1=plw1*pow((p1/(p11*0.5889)),2)" ; Water-flip-back pulse power
"cnst5=bf1*cnst19-o1*1000000"
"d10=3u"
"d11=30m"
"d25=p25"
"d26=1s/(cnst4*4)"
"in10=inf2/2"
"l11=0"
"DELTA=d26-p16-d16"
# ifdef LABEL_CN
"DELTA1=d26-p16-d16-larger(p2,p8)-d10*2-8u"
"spw13=plw2*pow((p3/((p8/2)*0.1023327)),2)" ; 13C 180 adiabatic pulse power
# else
"DELTA1=d26-p16-d16-p2-d10*2-8u"
# endif /*LABEL_CN*/
"DELTA2=d26-p19-d16"
"DELTA3=d26-p16-d16"
"DELTA4=p16+d16+4u"
"DELTA5=Teq-p16-d16-p5-8u"
"acqt0=0"
baseopt_echo
aqseq 312
1 ze
d11 pl16:f3
2 d11 do:f3
"va15N.idx=(l11*2)"
d1 pl19:f1 fq=300 (bf ppm):f1 pl3:f3 va15N.inc
;******************************************************* 1H & 15N heating compensation
if "va15N==1000"
{
4u cw:f1 va15N.dec
}
else
{
4u va15N.dec
}
(p21 ph3):f3
4u va15N:f3 va15N.inc
(p25 ph0):f3
4u do:f1
;******************************************************* end heating compensation
50u UNBLKGRAD
p16:gp6
d16 pl0:f1 fq=0 (sfo hz):f1
(p11:sp1 ph2):f1
4u
4u pl1:f1 fq=cnst5 (sfo hz):f1
(p1 ph0):f1
4u pl10:f1 pl22:f3
(Pcp ph7):f1 (Pcp ph8):f3 ; cross polarization
4u pl1:f1 pl3:f3
(p21 ph1):f3
p16:gp1
d16
(p5 ph1):f1
4u pl19:f1
4u cw:f1 ph0
DELTA5
(p23 ph1):f3
;******************************************************* Begin spinlock
4u va15N:f3
if "va15N==1000" goto 5
(p25 ph0):f3
;******************************************************* End spinlock
5 4u pl3:f3
(p23 ph3):f3
DELTA5
4u do:f1
4u pl1:f1
(p5 ph3):f1
p16:gp7
d16 fq=0 (sfo hz):f1
(p21 ph5):f3
;******************************************************* 15N chemical shift evolution + INEPT
p16:gp2*-1*EA
d16 pl1:f1
DELTA
(p22 ph4):f3
d10 gron0
4u groff
# ifdef LABEL_CN
(center (p2 ph0):f1 (p8:sp13 ph0):f2 )
# else
(p2 ph0):f1
# endif /*LABEL_CN*/
d10 gron0*-1
4u groff
p16:gp2*EA
d16
DELTA1
;******************************************************* PEP
(center (p1 ph2):f1 (p21 ph0):f3 )
p19:gp4
d16
DELTA2
(center (p2 ph3):f1 (p22 ph0):f3 )
DELTA2
p19:gp4
d16
(center (p1 ph3):f1 (p21 ph6):f3 )
p16:gp5
d16
DELTA3
(center (p2 ph3):f1 (p22 ph3):f3 )
DELTA3
p16:gp5
d16
(p1 ph0):f1
DELTA4
(p2 ph0):f1
p16:gp3
d16 pl16:f3
4u BLKGRAD
go=2 ph31 cpds3:f3
d11 mc #0 to 2
F1QF(calclc(l11, 1))
F2EA(calgrad(EA) & calph(ph6, +180), caldel(d10, +in10) & calph(ph5, +180) & calph(ph31, +180))
exit
ph0 = 0
ph1 = 1
ph2 = 2
ph3 = 3
ph4 = 0 0 0 0 2 2 2 2
ph5 = 1
ph6 = 3
ph7 = 1 3
ph8 = 0 0 2 2
ph31= 0 2 2 0
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl3 : f3 channel - power level for pulse (default)
;pl10: f1 channel - power level for CP
;pl16: f3 channel - power level for CPD/BB decoupling
;pl19: f1 channel - power level for CPD/BB decoupling
;pl22: f3 channel - power level for CP
;pl25: f3 channel - power level for R1rho spinlock (valist)
;pl26: f3 channel - power level for heat compensation (valist)
;sp1: f1 channel - shaped pulse 90 degree
;spnam1: Sinc1.1000
;sp13: f2 channel - shaped pulse 180 degree (adiabatic)
;spnam13: Crp60,0.5,20.1
;p1 : f1 channel - 90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel - 90 degree high power pulse
;p5 : f1 channel - X degree high power pulse
;p8 : f2 channel - 180 degree shaped pulse for inversion (adiabatic)
;p11: f1 channel - 90 degree selective pulse
;p16: homospoil/gradient pulse [1 msec]
;p19: gradient pulse 2 [500 usec]
;p21: f3 channel - 90 degree high power pulse
;p22: f3 channel - 180 degree high power pulse
;p23: f3 channel - X degree high power pulse
;p25: f3 channel - R1rho spinlock length
;d26: 1/(4J(YH))
;d1 : relaxation delay; 1-5 * T1
;d11: delay for disk I/O [30 msec]
;d16: delay for homospoil/gradient recovery
;cnst4: = J(YH)
;cnst9: CP power in Hz
;cnst10: spin-lock power in Hz
;cnst11: highest spin-lock power in Hz
;cnst19: amide 1H in ppm
;inf2: 1/SW(X) = 2 * DW(X)
;in10: 1/(2 * SW(X)) = DW(X)
;nd10: 2
;o3p: amide 15N in ppm
;nbl: number of powers in valist
;ns: 4 * n
;ds: >= 16
;td1: (number of powers)/2 in valist
;td2: number of experiments in F2
;FnMODE: QF in F1
;FnMODE: Echo-Antiecho in F2
;cpd3: decoupling according to sequence defined by cpdprg3
;pcpd3: f3 channel - 90 degree pulse for decoupling sequence
;use gradient ratio: gp 0 :gp 1 : gp 2 : gp 3 : gp 4 : gp 5 : gp 6 : gp 7
; 0.2 : 30 : 80 : 16.2 : 5 : -2 : 6 : -60
;for z-only gradients:
;gpz0: 0.2%
;gpz1: 30%
;gpz2: 80%
;gpz3:16.2%
;gpz4: 5%
;gpz5: -2%
;gpz6: 6%
;gpz7: -60%
;use gradient files:
;gpnam1: SMSQ10.100
;gpnam2: SMSQ10.100
;gpnam3: SMSQ10.100
;gpnam4: SMSQ10.50
;gpnam5: SMSQ10.100
;gpnam6: SMSQ10.100
;gpnam7: SMSQ10.100
;preprocessor-flags-start
;LABEL_CN: for C-13 and N-15 labeled samples start experiment with
; option -DLABEL_CN (eda: ZGOPTNS)
;preprocessor-flags-end
F1F2-selective [15N]-R1ρ relaxation dispersion (pseudo-4D version)¶
You can download the pulse program here - f1f2Nonr1rho4d
;f1f2Nonr1rho4d
;
;avance-version (07/15/2017)
;pseudo-3D F1F2(1H-15N)-selective N15 on-resonance R1rho relaxation dispersion
; using sensitivity improvement
;phase sensitive using Echo/Antiecho-TPPI gradient selection (t1)
;with decoupling during acquisition
;using f3 - channel
;acquisition as pseudo-4D
;
; F1(H) -(CP)-> F2(N) -> spin-lock(N) -> F2(N,t1) -> F1(H,t2)
;
;E. Walinda, D. Morimoto, M. Shirakawa, and K. Sugase,
; J. Biomol. NMR, 2017, 68 (1), 41-52
;
;$CLASS=HighRes
;$DIM=3D
;$TYPE=
;$SUBTYPE=
;$COMMENT=
;
;ignore the warning regarding va15N
#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>
define list<power> va15N=<$VALIST>
define list<frequency> fq1H=<$FQ1LIST>
define list<frequency> fq15N=<$FQ2LIST>
define list<pulse> vp1H=<$VPLIST>
define pulse Pcp
define delay Teq
"Pcp=10.8ms"
"Teq=5m"
"cnst2=3900" ; 1H decoupling power [Hz]
"p2=p1*2"
;"p5=(PI/2-atan(abs(cnst19-o1/bf1)*bf1/cnst2))*p1/(PI/2)"
"p22=p21*2"
"plw0=0"
"plw10=plw1*pow(p1/(250000/cnst9),2)" ; 1H CP power
"plw22=plw3*pow(p21/(250000/cnst9),2)" ; 15N CP power
"plw19=plw1*pow(p1/(250000/cnst2),2)" ; 1H decoupling power
"plw16=plw3*pow((p21/pcpd3),2)" ; 15N decoupling power
;"cnst10=250000/p21*sqrt(plw3/plw25)"
;"plw26=plw3*pow(p21/(250000/(cnst11-cnst10)),2)"; 15N heating compensation
"spw1=plw1*pow((p1/(p11*0.5889)),2)" ; Water-flip-back pulse power
;"cnst5=bf1*cnst19-o1*1000000"
"d10=3u"
"d11=30m"
"d26=1s/(cnst4*4)"
"in10=inf3/2"
"l11=0"
"l12=0"
"DELTA=d26-p16-d16"
# ifdef LABEL_CN
"DELTA1=d26-p16-d16-larger(p2,p8)-d10*2-8u"
"spw13=plw2*pow((p3/((p8/2)*0.1023327)),2)" ; 13C 180 adiabatic pulse power
# else
"DELTA1=d26-p16-d16-p2-d10*2-8u"
# endif /*LABEL_CN*/
"DELTA2=d26-p19-d16"
"DELTA3=d26-p16-d16"
"DELTA4=p16+d16+4u"
"DELTA5=Teq-p16-d16-vp1H-8u"
"acqt0=0"
baseopt_echo
;aqseq 312
1 ze
d11 pl16:f3
2 d11 do:f3
"fq1H.idx=(l12)"
"fq15N.idx=(l12)"
"vp1H.idx=(l12)"
"va15N.idx=(l11*2)"
d1 pl19:f1 fq=300 (bf ppm):f1 pl3:f3 fq15N:f3 va15N.inc
;******************************************************* 1H & 15N heating compensation
if "va15N==1000"
{
4u cw:f1 va15N.dec
}
else
{
4u va15N.dec
}
(p21 ph3):f3
4u va15N:f3 va15N.inc
(p25 ph0):f3
4u do:f1
;******************************************************* end heating compensation
50u UNBLKGRAD
p16:gp6
d16 pl0:f1 fq=0 (sfo hz):f1
(p11:sp1 ph2):f1
4u
4u pl1:f1 fq1H:f1
(p1 ph0):f1
4u pl10:f1 pl22:f3
(Pcp ph7):f1 (Pcp ph8):f3 ; cross polarization
4u pl1:f1 pl3:f3
(p21 ph1):f3
p16:gp1
d16
(vp1H ph1):f1
4u pl19:f1
4u cw:f1 ph0
DELTA5
(p21 ph1):f3
;******************************************************* Begin spinlock
4u va15N:f3
if "va15N==1000" goto 5
(p25 ph0):f3
;******************************************************* End spinlock
5 4u pl3:f3
(p21 ph3):f3
DELTA5
4u do:f1
4u pl1:f1
(vp1H ph3):f1
p16:gp7
d16 fq=0 (sfo hz):f1
(p21 ph5):f3
;******************************************************* 15N chemical shift evolution + INEPT
p16:gp2*-1*EA
d16 pl1:f1
DELTA
(p22 ph4):f3
d10 gron0
4u groff
# ifdef LABEL_CN
(center (p2 ph0):f1 (p8:sp13 ph0):f2 )
# else
(p2 ph0):f1
# endif /*LABEL_CN*/
d10 gron0*-1
4u groff
p16:gp2*EA
d16
DELTA1
;******************************************************* PEP
(center (p1 ph2):f1 (p21 ph0):f3 )
p19:gp4
d16
DELTA2
(center (p2 ph3):f1 (p22 ph0):f3 )
DELTA2
p19:gp4
d16
(center (p1 ph3):f1 (p21 ph6):f3 )
p16:gp5
d16
DELTA3
(center (p2 ph3):f1 (p22 ph3):f3 )
DELTA3
p16:gp5
d16
(p1 ph0):f1
DELTA4
(p2 ph0):f1
p16:gp3
d16 pl16:f3
4u BLKGRAD
go=2 ph31 cpds3:f3
d11 mc #0 to 2
F1QF(calclc(l12, 1))
F2QF(calclc(l11, 1))
F3EA(calgrad(EA) & calph(ph6, +180), caldel(d10, +in10) & calph(ph5, +180) & calph(ph31, +180))
exit
ph0 = 0
ph1 = 1
ph2 = 2
ph3 = 3
ph4 = 0 0 0 0 2 2 2 2
ph5 = 1
ph6 = 3
ph7 = 1 3
ph8 = 0 0 2 2
ph31= 0 2 2 0
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl3 : f3 channel - power level for pulse (default)
;pl10: f1 channel - power level for CP
;pl16: f3 channel - power level for CPD/BB decoupling
;pl19: f1 channel - power level for CPD/BB decoupling
;pl22: f3 channel - power level for CP
;pl25: f3 channel - power level for R1rho spinlock (valist)
;pl26: f3 channel - power level for heat compensation (valist)
;sp1: f1 channel - shaped pulse 90 degree
;spnam1: Sinc1.1000
;sp13: f2 channel - shaped pulse 180 degree (adiabatic)
;spnam13: Crp60,0.5,20.1
;p1 : f1 channel - 90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel - 90 degree high power pulse
;p8 : f2 channel - 180 degree shaped pulse for inversion (adiabatic)
;p11: f1 channel - 90 degree selective pulse
;p16: homospoil/gradient pulse [1 msec]
;p19: gradient pulse 2 [500 usec]
;p21: f3 channel - 90 degree high power pulse
;p22: f3 channel - 180 degree high power pulse
;p25: f3 channel - R1rho spinlock length
;d1 : relaxation delay; 1-5 * T1
;d11: delay for disk I/O [30 msec]
;d16: delay for homospoil/gradient recovery
;d26: 1/(4J(YH))
;cnst4: = J(YH)
;cnst9: CP power in Hz
;cnst10: spin-lock power in Hz
;cnst11: highest spin-lock power in Hz
;cnst19: amide 1H in ppm
;inf3: 1/SW(X) = 2 * DW(X)
;in10: 1/(2 * SW(X)) = DW(X)
;nd10: 2
;o3p: amide 15N in ppm
;nbl: number of powers in valist
;ns: 4 * n
;ds: >= 16
;td1: number of frequencies in fq-list
;td2: (number of powers)/2 in valist
;td3: number of experiments in F3
;FnMODE: QF in F1
;FnMODE: QF in F2
;FnMODE: Echo-Antiecho in F3
;cpd3: decoupling according to sequence defined by cpdprg3
;pcpd3: f3 channel - 90 degree pulse for decoupling sequence
;use gradient ratio: gp 0 :gp 1 : gp 2 : gp 3 : gp 4 : gp 5 : gp 6 : gp 7
; 0.2 : 30 : 80 : 16.2 : 5 : -2 : 6 : -60
;for z-only gradients:
;gpz0: 0.2%
;gpz1: 30%
;gpz2: 80%
;gpz3:16.2%
;gpz4: 5%
;gpz5: -2%
;gpz6: 6%
;gpz7: -60%
;use gradient files:
;gpnam1: SMSQ10.100
;gpnam2: SMSQ10.100
;gpnam3: SMSQ10.100
;gpnam4: SMSQ10.50
;gpnam5: SMSQ10.100
;gpnam6: SMSQ10.100
;gpnam7: SMSQ10.100
;preprocessor-flags-start
;LABEL_CN: for C-13 and N-15 labeled samples start experiment with
; option -DLABEL_CN (eda: ZGOPTNS)
;preprocessor-flags-end
F1F2-selective [15N]-ZZ exchange¶
You can download the pulse program here - f1f2Nzzhsqcgpsi
;f1f2Nzzhsqcgpsi
;
;avance-version (02/04/2020)
;2D H-1/N-15 cross polarization
; using sensitivity improvement
;phase sensitive using Echo/Antiecho-TPPI gradient selection (t1)
;with decoupling during acquisition
;ZZ-exchange
;
; F2(H) -(CP)-> F1(N) -(ZZ-exchange)-> F1(N,t1) -> F2(H,t2)
;
;M. Nishizawa, E. Walinda, D. Morimoto, and K. Sugase,
;
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=
#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>
define pulse Pcp
"Pcp=10.8ms"
"p2=p1*2"
"p22=p21*2"
"plw0=0"
"plw10=plw1*pow(p1/(250000/cnst9),2)" ; 1H CP power
"plw22=plw3*pow(p21/(250000/cnst9),2)" ; 15N CP power
"plw16=plw3*pow((p21/pcpd3),2)" ; 15N decoupling power
"spw1=plw1*pow((p1/(p11*0.5889)),2)" ; Water-flip-back pulse power
"spw12=plw1*pow((p1/(p12*0.07981016/2)),2)" ; amide proton selective 180 pulse
"cnst5=sfo1*cnst19-o1*1000000"
"d0=3u"
"d11=30m"
"d26=1s/(cnst4*4)"
"d31=10ms*l2+p16+d16"
"in0=inf1/2"
"DELTA=d26-p16-d16"
# ifdef LABEL_CN
"DELTA1=d26-p16-d16-larger(p2,p8)-d0*2-8u"
"spw13=plw2*pow((p3/((p8/2)*0.1023327)),2)" ; 13C 180 adiabatic pulse power
# else
"DELTA1=d26-p16-d16-p2-d0*2-8u"
# endif /*LABEL_CN*/
"DELTA2=d26-p19-d16"
"DELTA3=d26-p16-d16"
"DELTA4=p16+d16+4u"
"TAU=2.5m-p12/2"
"acqt0=0"
baseopt_echo
1 ze
d11 pl16:f3
2 d11 do:f3
d1 pl0:f1
50u UNBLKGRAD
(p11:sp1 ph2):f1
4u
4u pl1:f1 fq=cnst5 (sfo hz):f1
(p1 ph0):f1
4u pl10:f1 pl22:f3
(Pcp ph7):f1 (Pcp ph8):f3 ; cross polarization
4u pl3:f3
(p21 ph1):f3
;******************************************** ZZ-exchange
p16:gp1
d16 pl0:f1 fq=0 (sfo hz):f1
if "l2==0" goto 4
3 TAU
(p12:sp12 ph0):f1
TAU
TAU
(p12:sp12 ph0):f1
TAU
lo to 3 times l2
4 (p21 ph5):f3
;******************************************************* 15N chemical shift evolution + INEPT
p16:gp2*-1*EA
d16 pl1:f1
DELTA
(p22 ph4):f3
d0 gron0*-1
4u groff
# ifdef LABEL_CN
(center (p2 ph0):f1 (p8:sp13 ph0):f2 )
# else
(p2 ph0):f1
# endif /*LABEL_CN*/
d0 gron0
4u groff
p16:gp2*EA
d16
DELTA1
;******************************************************* PEP
(center (p1 ph2):f1 (p21 ph0):f3 )
p19:gp4
d16
DELTA2
(center (p2 ph3):f1 (p22 ph0):f3 )
DELTA2
p19:gp4
d16
(center (p1 ph3):f1 (p21 ph6):f3 )
p16:gp5
d16
DELTA3
(center (p2 ph3):f1 (p22 ph3):f3 )
DELTA3
p16:gp5
d16
(p1 ph0):f1
DELTA4
(p2 ph0):f1
p16:gp3
d16 pl16:f3
4u BLKGRAD
go=2 ph31 cpds3:f3
d11 do:f3 mc #0 to 2
F1EA(calgrad(EA) & calph(ph6, +180), caldel(d0, +in0) & calph(ph5, +180) & calph(ph31, +180))
exit
ph0 = 0
ph1 = 1
ph2 = 2
ph3 = 3
ph4 = 0 0 0 0 2 2 2 2
ph5 = 1
ph6 = 3
ph7 = 1 3
ph8 = 0 0 2 2
ph31= 0 2 2 0
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl3 : f3 channel - power level for pulse (default)
;pl10: f1 channel - power level for CP
;pl16: f3 channel - power level for CPD/BB decoupling
;pl22: f3 channel - power level for CP
;sp1: f1 channel - shaped pulse 90 degree
;spnam1: Sinc1.1000
;sp12: f1 channel - shaped pulse 180 degree
;spnam12: Reburp.1000
;sp13: f2 channel - shaped pulse 180 degree (adiabatic)
;spnam13: Crp60,0.5,20.1
;p1 : f1 channel - 90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel - 90 degree high power pulse
;p8 : f2 channel - 180 degree shaped pulse for inversion (adiabatic)
;p11: f1 channel - 90 degree selective pulse
;p12: f1 channel - 180 degree shaped pulse [3 msec]
;p21: f3 channel - 90 degree high power pulse
;p22: f3 channel - 90 degree high power pulse
;p16: homospoil/gradient pulse [1 msec]
;p19: gradient pulse 2 [500 usec]
;d1 : relaxation delay; 1-5 * T1
;d8 : mixing time
;d11: delay for disk I/O [30 msec]
;d16: delay for homospoil/gradient recovery
;d26: 1/(4J(NH))
;d31: actual mixingi time
;cnst4: = J(NH)
;cnst9: CP power in Hz
;cnst19: amide 1H in ppm
;l2: ZZ-exchange cycles, Mixing time = 10ms x l2
;o3p: amide 15N in ppm
;inf1: 1/SW(N) = 2 * DW(N)
;in0: 1/(2 * SW(N)) = DW(N)
;nd0: 2
;ns: 4 * n
;ds: >= 8
;td1: number of experiments in F1
;FnMODE: Echo-Antiecho in F1
;cpd3: decoupling according to sequence defined by cpdprg3
;pcpd3: f3 channel - 90 degree pulse for decoupling sequence
;use gradient ratio: gp 0 : gp 1 : gp 2 : gp 3 : gp 4 : gp 5
; 0.2 : 30 : 80 : 16.2 : 5 : -2
;for z-only gradients:
;gpz0: 0.2%
;gpz1: 30%
;gpz2: 80%
;gpz3:16.2%
;gpz4: 5%
;gpz5: -2%
;use gradient files:
;gpnam1: SMSQ10.100
;gpnam2: SMSQ10.100
;gpnam3: SMSQ10.100
;gpnam4: SMSQ10.50
;gpnam5: SMSQ10.100
;preprocessor-flags-start
;LABEL_CN: for C-13 and N-15 labeled samples start experiment with
; option -DLABEL_CN (eda: ZGOPTNS)
;preprocessor-flags-end